Contents

Comparison of Pascal and Delphi

Devised by Niklaus Wirth in the late 1960s and early 1970s, Pascal is a programming language. Originally produced by Borland Software Corporation, Embarcadero Delphi is composed of an IDE, set of standard libraries, and a Pascal-based language commonly called either Object Pascal, Delphi Pascal, or simply 'Delphi' (Embarcadero's current documentation refers to it as 'the Delphi language (Object Pascal)'^[1]). Since first released, it has become the most popular commercial Pascal implementation.

While developing Pascal, Wirth employed a bootstrapping procedure in which each newer version of the Pascal compiler was written and compiled with its predecessor. Thus, the 'P2' compiler was written in the dialect compilable by 'P1', 'P3' in turn was written in 'P2' and so on, all the way till 'P5'. The 'P5' compiler implemented Pascal in its final state as defined by Wirth, and subsequently became standardised as 'ISO 7185 Pascal'.

The Borland dialect, like the popular UCSD Pascal before it, took the 'P4' version of the language as its basis, rather than Wirth's final revision. After much evolution independent of Standard Pascal, the Borland variant became the basis for Delphi. This page goes over the differences between Delphi and Standard Pascal. It does not go into Delphi-specific extensions to the language, which are numerous and still increasing.

Following features are mutually exclusive. The Standard Pascal implementation is not accepted by Delphi and vice versa, the Delphi code is not acceptable in Standard Pascal.

Standard Pascal has a Euclidean-like definition of the mod operator whereas Delphi uses a truncated definition.

Standard Pascal requires that the comment delimiters { and the bigramm (*, as well as } and *) are synonymous to each other.^[2] In Delphi, however, a block comment started by { must be closed with a }.^[3] The bigramm *) will only close any comment that started with (*.^[3] This scheme allows for nested comments at the expense of compiler complexity.

The way procedures and functions can be passed as parameters differs: Delphi requires explicit procedural types to be declared where Standard Pascal does not.^[4]

program proceduralDataType(output);

 { `printYIntersect` has one procedural parameter: }
 procedure printYIntersect(function f(x: real): real);
  begin
   writeLn(f(0.0));
  end;
 { Standard Pascal does not have procedural “pointers.” }
 function f(x: real): real;
  begin
   f := cos(x);
  end;
 { ─── MAIN ───────────────────────────────────────────── }
 begin
  printYIntersect(f);
 end.

type
 TFunc = function(x: real): real;

procedure printYIntersect(f: TFunc);
 begin
  writeLn(f(0.0));
 end;

function f(x: real): real;
 begin
  f := cos(x);
 end;
// ─── MAIN ─────────────────────────────────────────────
begin
 printYIntersect(@f);
end.

Various computer systems show a wide variety how to indicate a newline. This affects the internal representation of text files which are composed of a series of “lines”. In order to relieve the programmer from any associated headaches, Standard Pascal mandates that reading an “end-of-line character” returns a single space character. To distinguish such an “end-of-line” space character from a space character that is actually genuine payload of the line, EOLn becomes true.

Delphi does not show this behavior. Reading a newline will return whatever character sequence represents a newline on the current host system, for example two char values chr(13) (carriage return) plus chr(10) (line feed).^[3]

Following features are present or missing in either language.

Standard Pascal permits a goto to any label defined in scope. In Delphi a goto must be within the current routine, i. e. may not leave the begin … end-frame.^[3]

program jumpAround;
 label
  999;
 procedure foo;
  begin
   { This is not permitted in Delphi: }
   goto 999;
  end;
 begin
  foo;
  999: ;
 end.

Delphi does not support buffer variables and associated standard routines get and put.^[3]

program copy(input, output);
 begin
  while not EOF(input) do
  begin
   { Copy file buffers. Not supported by Delphi }
   output↑ := input↑;
   
   { Input↑ contains a space if a new-line occurred. }
   if EOLn(input) then
   begin
    writeLn(output);
   end
   else
   begin
    put(output);
   end;
   
   { Advance reading cursor. }
   get(input);
  end;
 end.

In Standard Pascal allocating memory for a variant record may indicate a specific variant. This allows implementations to allocate the least amount of really necessary memory. Delphi does not support this.^[3]

program variantRecord;
 type
  sex = (female, male);
  clothingMeasures = record
    girth: real;
    case gender: sex of
     female: (underbust: real);
     male: ( );
   end;
 var
  size: clothingMeasures;
 begin
  { NB: No space allocated for `underbust`. }
  new(size, male);
 end.

In Delphi any file must be backed by a file in the file system. That means any file needs to be associated with a file name with Delphi's assign procedure. In contrast, Standard Pascal is usable without file names. The following will produce a run-time error with Delphi.^[3]

program temporaryFile(output);
 var
  FD: text;
 begin
  rewrite(FD);
  writeLn(FD, 'Hello world!');
 end.

Delphi does not implement the standard procedures pack and unpack.^[3] Regardless, transferring data between packed and unpacked data types is an easy feat, although the implementation might not be as efficient as a compiler vendor supplied implementation would be.

Delphi does not associate the data type Boolean with a default width if specified as write/writeLn parameters.^[3] Delphi demonstrates the behavior as usual for character-strings.

Delphi permits overloading routines. In Standard Pascal identifiers must be unique in every block.

function f(x: integer): real;
begin
 result := sin(x);
end;

function f(x: real): real;
begin
 result := cos(x);
end;
// ─── MAIN ─────────────────────────────────────────────
begin
 // Note the different data types.
 writeLn(f(3));
 writeLn(f(3.0));
end.

Delphi permits default parameters.

In Pascal, if the destination file is a text file, the parameters to write/writeLn have an implemention-defined default total width. In Delphi, for integer values this is simply 1. That means always the least amount of space is occupied.^[3] Other compilers have shown default widths of, for example, 20 allowing for a fine tabular look at no cost of extra code.

writeLn(1);
writeLn(23456789);

          1
   23456789

1
23456789

• Kathleen Jansen and Niklaus Wirth: PASCAL - User Manual and Report. Springer-Verlag, 1974, 1985, 1991, ISBN 0-387-97649-3, ISBN 0-387-90144-2, and ISBN 3-540-90144-2 [1]
• Niklaus Wirth: The Programming Language Pascal. Acta Informatica, 1, (Jun 1971) 35–63
• ISO/IEC 7185: Programming Languages - PASCAL. [2]
• Doug Cooper: Standard Pascal: User Reference Manual. W. W. Norton & Company, 1983, ISBN 0-393-30121-4, ISBN 978-0-393-30121-2

• The ISO 7185 Pascal web site
• Pascal standards documents